hedera-account/configure.ac

dnl Process this file with autoconf to produce a configure script.
dnl Created by Anjuta application wizard.

AC_INIT(hedera-account, 1.0)

AC_CONFIG_HEADERS([build/config.h])
AC_CONFIG_AUX_DIR([build])
AC_CONFIG_MACRO_DIR([build/m4])

AM_INIT_AUTOMAKE([-Wno-portability])

AM_SILENT_RULES([yes])

AC_PROG_CC

dnl Check for vala.
dnl You should change the version shown here manually to match with yours.
AM_PROG_VALAC([0.24])

dnl Internationalization
IT_PROG_INTLTOOL([0.35.0])

GETTEXT_PACKAGE=hedera-account
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [GETTEXT package name])
AM_GLIB_GNU_GETTEXT
AM_XGETTEXT_OPTION([-k_ -kQ_:1g -kN_ -kC_:1c,2 -kNC_:1c,2])

AC_MSG_CHECKING([whether to build with debug information...])
AC_ARG_ENABLE([debug],
	[AS_HELP_STRING([--enable-debug],
		[Enable debug data generation (default = no)])],
	[ENABLE_DEBUG="$enableval"],
	[ENABLE_DEBUG=no])
AC_MSG_RESULT([$ENABLE_DEBUG])

if test x"$ENABLE_DEBUG" = x"yes"; then
	CFLAGS=" -ggdb -O0 "
	VALAFLAGS=" -g --save-temps "
else
	CFLAGS=" -O2 "
	VALAFLAGS=
fi

AC_MSG_CHECKING([whether C warnings will be shown...])
AC_ARG_ENABLE([c-warnings],
	[AS_HELP_STRING([--enable-c-warnings],
		[Enable C warnings to be shown (default = no)])],
	[C_WARNINGS="$enableval"],
	[C_WARNINGS=no])
AC_MSG_RESULT([$C_WARNINGS])

if test x"$C_WARNINGS" = x"yes"; then
	CFLAGS+=" -Wall "
else
	CFLAGS+=" -w "
fi

AC_SUBST([CFLAGS])
AC_SUBST([VALAFLAGS])

LT_INIT

AC_ARG_VAR([UNINSTALLED_DIR], [the directory of the uninstalled hedera project])
: ${UNINSTALLED_DIR=''}

PKG_PROG_PKG_CONFIG

VALAFLAGS+=" --pkg posix "

if test $UNINSTALLED_DIR; then
	VALA_CHECK_MODULES(ACCOUNT, [gtk+-3.0])
	ACCOUNT_CFLAGS+=-I$UNINSTALLED_DIR
	ACCOUNT_LIBS+=$UNINSTALLED_DIR/build/main/libhedera.la
	VALAFLAGS+="$ACCOUNT_VALAFLAGS --pkg gvn --pkg sql --pkg db --pkg vn --vapidir $UNINSTALLED_DIR/build/vapi"

	AC_SUBST(account_libdir, $libdir/hedera/module)
	AC_SUBST(account_datadir, $datadir/hedera/module)
	AC_SUBST(querydir, $account_datadir/sql)
else
	VALA_CHECK_MODULES(ACCOUNT, [hedera])
	VALAFLAGS+=$ACCOUNT_VALAFLAGS

	PKG_CHECK_VAR([account_libdir], [hedera], [modulelibdir])
	PKG_CHECK_VAR([account_datadir], [hedera], [moduledatadir])
	PKG_CHECK_VAR([querydir], [hedera], [modulequerydir])
fi

AC_OUTPUT([
	Makefile
	src/Makefile
	data/Makefile
	po/Makefile.in])