AC_INIT([hedera], [1.0])
dnl Set compiler flags empty by default
: ${CFLAGS=''}

AC_CONFIG_AUX_DIR([build])
AC_CONFIG_MACRO_DIR([build/m4])
AC_CONFIG_HEADERS([build/config.h])
LT_INIT([dlopen])
AC_PREREQ([2.69])
AM_SILENT_RULES([yes])

# Checks for the C compiler
AC_PROG_CC

# Check for additional packages
PKG_CHECK_MODULES([glib], [glib-2.0])
PKG_CHECK_MODULES([gdome], [gdome2])
PKG_CHECK_MODULES([gtk], [gtk+-3.0])
PKG_CHECK_MODULES([gladeui], [gladeui-2.0])
PKG_CHECK_MODULES([gtksourceview], [gtksourceview-3.0]
	,[SOURCEVIEW=yes]
	,[echo $gtksourceview_PKG_ERRORS])

AM_CONDITIONAL(HAVE_SOURCEVIEW, [test -n $SOURCEVIEW])

GTK_DOC_CHECK([1.14],[--flavour no-tmpl])

# Internationalization
IT_PROG_INTLTOOL([0.40.1], [no-xml])

GETTEXT_PACKAGE=hedera
AC_SUBST([GETTEXT_PACKAGE])
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [GETTEXT package name])
ALL_LINGUAS="es ca nl"
AM_GLIB_GNU_GETTEXT
AM_XGETTEXT_OPTION([-k_ -kQ_:1g -kN_ -kC_:1c,2 -kNC_:1c,2])

# Checks for Ragel State Machine Compiler
AC_PATH_PROG(RAGEL, [ragel], [no])
if test x"$RAGEL" = x"no" ; then
	AC_MSG_ERROR([Ragel State Machine Compiler (ragel) not found.])
fi

# Checks if Vala bindings should be generated
AC_MSG_CHECKING([wether to generate Vala bindings...])
AC_ARG_ENABLE([vala],
	[AS_HELP_STRING([--enable-vala],
		[Enable vala bindings generation [default = no]])],
		[ENABLE_VALA="$enableval"],
		[ENABLE_VALA=no])
AC_MSG_RESULT([$ENABLE_VALA])

AM_CONDITIONAL(HAVE_INTROSPECTION, [test FALSE])

if test x"$ENABLE_VALA" = x"yes" ; then
	GOBJECT_INTROSPECTION_CHECK([1.30.0])
	AC_SUBST([GIR_SCANNER_ARGS], [--warn-all])
	if $HAVE_INTROSPECTION; then
		AC_SUBST([VALA_VERSION], [0.24])
		AM_PROG_VALAC([$VALA_VERSION])
		AC_PATH_PROG(VAPIGEN, [vapigen], ["no"])
	fi
fi

AM_CONDITIONAL(ENABLE_VALA, [test x"$ENABLE_VALA" = x"yes" -a x"$VAPIGEN" != x"no"])

# GSettings configuration
GLIB_GSETTINGS

# Sets the default build options for Vn projects 
VN_BUILD_OPTIONS

if test x"$ENABLE_INSTALL" != x"yes"; then
	glib-compile-schemas --targetdir . ../vn/schema
fi

# Portability check disabled for GTK-DOC (can be changed if needed)
AM_INIT_AUTOMAKE([-Wno-portability])
AC_CONFIG_FILES([
	Makefile
	gvn/gvn.pc
	sql/sql.pc
	db/db.pc
	vn/vn.pc
	main/hedera.pc
	gvn/Makefile
	sql/Makefile
	sql/parser/Makefile
	db/Makefile
	plugin/Makefile
	plugin/pg/Makefile
	plugin/mysql/Makefile
	vn/Makefile
	vn/field/Makefile
	vn/column/Makefile
	module/Makefile
	module/src/Makefile
	module/data/Makefile
	main/Makefile
	main/vn-hedera.desktop
	vapi/Makefile
	glade/Makefile
	docs/Makefile
	docs/reference/Makefile
	docs/reference/hedera/Makefile
	po/Makefile.in
	anjuta/Makefile
])

AC_SUBST([uVERSION], [${VERSION//./_}])
AC_SUBST([VERSION_INFO], [${VERSION//./:}])

AC_OUTPUT