AC_INIT([hedera], [1.0])

AC_CONFIG_AUX_DIR([build])
AC_CONFIG_MACRO_DIR([build/m4])
AC_CONFIG_HEADERS([build/config.h])
LT_INIT([dlopen])
AC_PREREQ([2.69])
AM_SILENT_RULES([yes])

# Checks for programs
AC_PROG_CC

PKG_CHECK_MODULES([glib], [glib-2.0])
PKG_CHECK_MODULES([gdome], [gdome2])
PKG_CHECK_MODULES([gtk], [gtk+-3.0])
PKG_CHECK_MODULES([gladeui], gladeui-2.0)

GTK_DOC_CHECK([1.14],[--flavour no-tmpl])
IT_PROG_INTLTOOL([0.40.1], [no-xml])

# Checks for Ragel State Machine Compiler
AC_PATH_PROG(RAGEL, [ragel], [no])
if test x"$RAGEL" = x"no" ; then
	AC_MSG_ERROR([Ragel State Machine Compiler (ragel) not found.])
fi

# Checks if Vala bindings should be generated
dnl TODO: Use AC_ARG_WITH to pick the Vala version?
AC_MSG_CHECKING([wether to generate Vala bindings...])
AC_ARG_ENABLE([vala],
	[AS_HELP_STRING([--enable-vala],
		[Enable vala bindings generation [default = no]])],
		[ENABLE_VALA="$enableval"],
		[ENABLE_VALA=no])
AC_MSG_RESULT([$ENABLE_VALA])

AM_CONDITIONAL(HAVE_INTROSPECTION, [test FALSE])

if test x"$ENABLE_VALA" = x"yes" ; then
	GOBJECT_INTROSPECTION_CHECK([1.30.0])
	AC_SUBST([GIR_SCANNER_ARGS], [--warn-all])
	if $HAVE_INTROSPECTION; then
		AC_SUBST([VALA_VERSION], [0.20])
		AM_PROG_VALAC([$VALA_VERSION])
		AC_PATH_PROG(VAPIGEN, [vapigen], ["no"])
	fi
fi

AM_CONDITIONAL(ENABLE_VALA, [test x"$ENABLE_VALA" = x"yes" -a x"$VAPIGEN" != x"no"])

# Internationalization
GETTEXT_PACKAGE=hedera
AC_SUBST([GETTEXT_PACKAGE])
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [GETTEXT package name])
ALL_LINGUAS="es ca nl"
AM_GLIB_GNU_GETTEXT
AM_XGETTEXT_OPTION([-k_ -kQ_:1g -kN_ -kC_:1c,2 -kNC_:1c,2])

# GSettings configuration
GLIB_GSETTINGS

CFLAGS=" -Wall"
 
# Check for debug mode
AC_MSG_CHECKING([whether to build with debug information...])
AC_ARG_ENABLE([debug],
	[AS_HELP_STRING([--enable-debug],
		[Enable debug data generation [default = no]])],
	[ENABLE_DEBUG="$enableval"],
	[ENABLE_DEBUG=no])
AC_MSG_RESULT([$ENABLE_DEBUG])

if test x"$ENABLE_DEBUG" = x"yes"; then
	CFLAGS+=" -ggdb"
fi

# Check if it will be installed
AC_MSG_CHECKING([whether to configure to install...])
AC_ARG_ENABLE([install],
	[AS_HELP_STRING([--enable-install],
		[Enable install configuration [default = yes]])],
	[ENABLE_INSTALL="$enableval"],
	[ENABLE_INSTALL=yes])
AC_MSG_RESULT([$installit])
AM_CONDITIONAL(ENABLE_INSTALL, [test x"$ENABLE_INSTALL" = x"yes"])

if test x"$ENABLE_INSTALL" = x"yes"; then
	CFLAGS+=" -O3"
else
	CFLAGS+=" -O0"
fi

AC_SUBST([CPPFLAGS])
AC_SUBST([CFLAGS])
AC_SUBST([LDFLAGS])

# Portability check disabled for GTK-DOC (can be changed if needed)
AM_INIT_AUTOMAKE([-Wno-portability])
AC_CONFIG_FILES([
	Makefile
	gvn/gvn.pc
	sql/sql.pc
	db/db.pc
	vn/vn.pc
	main/hedera.pc
	gvn/Makefile
	sql/Makefile
	sql/parser/Makefile
	db/Makefile
	plugin/Makefile
	plugin/pg/Makefile
	plugin/mysql/Makefile
	vn/Makefile
	vn/field/Makefile
	vn/column/Makefile
	module/Makefile
	module/src/Makefile
	module/data/Makefile
	module/sql/Makefile
	main/Makefile
	main/vn-hedera.desktop
	vapi/Makefile
	glade/Makefile
	docs/Makefile
	docs/reference/Makefile
	docs/reference/hedera/Makefile
	po/Makefile.in
])

AC_SUBST([uVERSION], [${VERSION//./_}])

AC_OUTPUT