salix-front/Jenkinsfile

#!/usr/bin/env groovy

def PROTECTED_BRANCH
def IS_LATEST

def BRANCH_ENV = [
    test: 'test',
    master: 'production',
    beta: 'production'
]

node {
    stage('Setup') {
        env.NODE_ENV = BRANCH_ENV[env.BRANCH_NAME] ?: 'dev'

        PROTECTED_BRANCH = [
            'dev',
            'test',
            'master',
            'main',
            'beta'
        ].contains(env.BRANCH_NAME)

        IS_LATEST = ['master', 'main'].contains(env.BRANCH_NAME)

        // https://www.jenkins.io/doc/book/pipeline/jenkinsfile/#using-environment-variables
        echo "NODE_NAME: ${env.NODE_NAME}"
        echo "WORKSPACE: ${env.WORKSPACE}"

        configFileProvider([
            configFile(fileId: 'salix-front.properties',
            variable: 'PROPS_FILE')
        ]) {
            def props = readProperties file: PROPS_FILE
            props.each {key, value -> env."${key}" = value }
            props.each {key, value -> echo "${key}: ${value}" }
        }

        if (PROTECTED_BRANCH) {
            configFileProvider([
                configFile(fileId: "salix-front.branch.${env.BRANCH_NAME}",
                variable: 'BRANCH_PROPS_FILE')
            ]) {
                def props = readProperties file: BRANCH_PROPS_FILE
                props.each {key, value -> env."${key}" = value }
                props.each {key, value -> echo "${key}: ${value}" }
            }
        }
    }
}

pipeline {
    agent any
    options {
        disableConcurrentBuilds()
    }
    tools {
        nodejs 'node-v18'
    }
    environment {
        PROJECT_NAME = 'lilium'
    }
    stages {
        stage('Version') {
            when {
                expression { PROTECTED_BRANCH }
            }
            steps {
                script {
                    def packageJson = readJSON file: 'package.json'
                    def version = "${packageJson.version}-build${env.BUILD_ID}"
                    writeFile(file: 'VERSION.txt', text: version)
                    echo "VERSION: ${version}"
                }
            }
        }
        stage('Install') {
            environment {
                NODE_ENV = ""
            }
            steps {
                sh 'pnpm install --prefer-offline'
            }
        }
        stage('Test') {
            when {
                expression { !PROTECTED_BRANCH }
            }
            environment {
                NODE_ENV = ""
            }
            parallel {
                stage('Unit') {
                    steps {
                        sh 'pnpm run test:unit:ci'
                    }
                    post {
                        always {
                            junit(
                                testResults: 'junitresults.xml',
                                allowEmptyResults: true
                            )
                        }
                    }
                }
                stage('E2E') {
                    environment {
                        CREDENTIALS = credentials('docker-registry')
                        COMPOSE_PROJECT = "${PROJECT_NAME}-${env.BUILD_ID}"
                        COMPOSE_PARAMS = "-p ${env.COMPOSE_PROJECT} -f test/cypress/docker-compose.yml --project-directory ."
                        TZ = 'Europe/Madrid'
                        CI = 'true'
                    }
                    steps {
                        script {
                            def image = docker.build('lilium-dev', '-f docs/Dockerfile.dev docs')
                            sh "docker-compose ${env.COMPOSE_PARAMS} up -d"
                            image.inside("--network ${env.COMPOSE_PROJECT}_default -e CI -e TZ") {
                                sh 'cypress run --browser chromium --spec test/cypress/integration/claim/claimAction.spec.js'
                            }
                        }
                    }
                    post {
                        always {
                            sh "docker-compose ${env.COMPOSE_PARAMS} down"
                            junit(
                                testResults: 'e2e-junitresults.xml',
                                allowEmptyResults: true
                            )
                        }
                    }
                }
            }
        }
        stage('Build') {
            when {
                expression { PROTECTED_BRANCH }
            }
            environment {
                CREDENTIALS = credentials('docker-registry')
                VERSION = readFile 'VERSION.txt'
            }
            steps {
                script {
                    sh 'quasar build'

                    def baseImage = "salix-frontend:${env.VERSION}"
                    def image = docker.build(baseImage, ".")
                    docker.withRegistry("https://${env.REGISTRY}", 'docker-registry') {
                        image.push()
                        image.push(env.BRANCH_NAME)
                        if (IS_LATEST) image.push('latest')
                    }
                }
            }
        }
        stage('Deploy') {
            when {
                expression { PROTECTED_BRANCH }
            }
            environment {
                VERSION = readFile 'VERSION.txt'
            }
            steps {
                withKubeConfig([
                    serverUrl: "$KUBERNETES_API",
                    credentialsId: 'kubernetes',
                    namespace: 'lilium'
                ]) {
                    sh 'kubectl set image deployment/lilium-$BRANCH_NAME lilium-$BRANCH_NAME=$REGISTRY/salix-frontend:$VERSION'
                }
            }
        }
    }
}