salix-front/Jenkinsfile

#!/usr/bin/env groovy

def PROTECTED_BRANCH

def BRANCH_ENV = [
    test: 'test',
    master: 'production',
    beta: 'production'
]

node {
    stage('Setup') {
        env.FRONT_REPLICAS = 1
        env.NODE_ENV = BRANCH_ENV[env.BRANCH_NAME] ?: 'dev'

        PROTECTED_BRANCH = [
            'dev',
            'test',
            'master',
            'beta'
        ].contains(env.BRANCH_NAME)

        // https://www.jenkins.io/doc/book/pipeline/jenkinsfile/#using-environment-variables
        echo "NODE_NAME: ${env.NODE_NAME}"
        echo "WORKSPACE: ${env.WORKSPACE}"

        configFileProvider([
            configFile(fileId: 'salix-front.properties',
            variable: 'PROPS_FILE')
        ]) {
            def props = readProperties file: PROPS_FILE
            props.each {key, value -> env."${key}" = value }
            props.each {key, value -> echo "${key}: ${value}" }
        }

        if (PROTECTED_BRANCH) {
            configFileProvider([
                configFile(fileId: "salix-front.branch.${env.BRANCH_NAME}",
                variable: 'BRANCH_PROPS_FILE')
            ]) {
                def props = readProperties file: BRANCH_PROPS_FILE
                props.each {key, value -> env."${key}" = value }
                props.each {key, value -> echo "${key}: ${value}" }
            }
        }
    }
}

pipeline {
    agent any
    options {
        disableConcurrentBuilds()
    }
    tools {
        nodejs 'node-v18'
    }
    environment {
        PROJECT_NAME = 'lilium'
    }
    stages {
        stage('Install') {
            environment {
                NODE_ENV = ""
            }
            steps {
                sh 'pnpm install --prefer-offline'
            }
        }
        stage('Test') {
            when {
                expression { !PROTECTED_BRANCH }
            }
            environment {
                NODE_ENV = ""
            }
            parallel {
                stage('Unit') {
                    steps {
                        sh 'pnpm run test:unit:ci'
                    }
                    post {
                        always {
                            junit(
                                testResults: 'junitresults.xml',
                                allowEmptyResults: true
                            )
                        }
                    }
                }
                stage('E2E') {
                    environment {
                        CREDENTIALS = credentials('docker-registry')
                        CI = "true"
                        TZ = 'Europe/Madrid'
                        COMPOSE_PROJECT = "${PROJECT_NAME}-${env.BRANCH_NAME}-${env.BUILD_ID}".toLowerCase()
                        COMPOSE_PARAMS = "--project-name ${env.COMPOSE_PROJECT} --project-directory . --file test/cypress/docker-compose.yml"
                    }
                    steps {
                        script {
                            sh "docker-compose ${env.COMPOSE_PARAMS} up -d"

                            def image = docker.build('cypress-setup', '-f ./test/cypress/Dockerfile .')
                            image.inside("--network ${env.COMPOSE_PROJECT}_default -e TZ -e CI") {
                                sh 'pwd'
                                sh 'ls -l'
                                sh 'whoami'
                                sh 'id -u'
                                sh 'cypress install'
                                sh 'cypress run --browser chromium --spec test/cypress/integration/claim/claimAction.spec.js'
                            }
                        }
                    }
                    post {
                        always {
                            sh "docker-compose ${env.COMPOSE_PARAMS} down"
                        }
                    }
                }
            }
        }
        stage('Build') {
            when {
                expression { PROTECTED_BRANCH }
            }
            environment {
                CREDENTIALS = credentials('docker-registry')
            }
            steps {
                sh 'quasar build'
                script {
                    def packageJson = readJSON file: 'package.json'
                    env.VERSION = "${packageJson.version}-build${env.BUILD_ID}"
                }
                dockerBuild()
            }
        }
        stage('Deploy') {
            when {
                expression { PROTECTED_BRANCH }
            }
            steps {
                script {
                    def packageJson = readJSON file: 'package.json'
                    env.VERSION = "${packageJson.version}-build${env.BUILD_ID}"
                }
                withKubeConfig([
                    serverUrl: "$KUBERNETES_API",
                    credentialsId: 'kubernetes',
                    namespace: 'lilium'
                ]) {
                    sh 'kubectl set image deployment/lilium-$BRANCH_NAME lilium-$BRANCH_NAME=$REGISTRY/salix-frontend:$VERSION'
                }
            }
        }
    }
}