#!/usr/bin/env groovy

def PROTECTED_BRANCH
def IS_LATEST

def BRANCH_ENV = [
    test: 'test',
    master: 'production',
    beta: 'production'
]

node {
    stage('Setup') {
        env.NODE_ENV = BRANCH_ENV[env.BRANCH_NAME] ?: 'dev'
        PROTECTED_BRANCH = [
            'dev',
            'test',
            'master',
            'main',
            'beta'
        ]

        IS_PROTECTED_BRANCH = PROTECTED_BRANCH.contains(env.BRANCH_NAME)
        IS_LATEST = ['master', 'main'].contains(env.BRANCH_NAME)

       // https://www.jenkins.io/doc/book/pipeline/jenkinsfile/#using-environment-variables
        echo "NODE_NAME: ${env.NODE_NAME}"
        echo "WORKSPACE: ${env.WORKSPACE}"
        echo "CHANGE_TARGET: ${env.CHANGE_TARGET}"

        configFileProvider([
            configFile(fileId: 'salix-front.properties',
            variable: 'PROPS_FILE')
        ]) {
            def props = readProperties file: PROPS_FILE
            props.each {key, value -> env."${key}" = value }
            props.each {key, value -> echo "${key}: ${value}" }
        }

        if (IS_PROTECTED_BRANCH) {
            configFileProvider([
                configFile(fileId: "salix-front.branch.${env.BRANCH_NAME}",
                variable: 'BRANCH_PROPS_FILE')
            ]) {
                def props = readProperties file: BRANCH_PROPS_FILE
                props.each {key, value -> env."${key}" = value }
                props.each {key, value -> echo "${key}: ${value}" }
            }
        }
    }
}

pipeline {
    agent any
    options {
        disableConcurrentBuilds()
    }
    tools {
        nodejs 'node-v18'
    }
    environment {
        PROJECT_NAME = 'lilium'
    }
    stages {
        stage('Version') {
            when {
                expression { IS_PROTECTED_BRANCH }
            }
            steps {
                script {
                    def packageJson = readJSON file: 'package.json'
                    def version = "${packageJson.version}-build${env.BUILD_ID}"
                    writeFile(file: 'VERSION.txt', text: version)
                    echo "VERSION: ${version}"
                }
            }
        }
        stage('Install') {
            environment {
                NODE_ENV = ""
            }
            steps {
                sh 'pnpm install --prefer-offline'
            }
        }
        stage('Test') {
            when {
                expression { !IS_PROTECTED_BRANCH }
            }
            environment {
                NODE_ENV = ''
                CI = 'true'
                TZ = 'Europe/Madrid'
            }
            parallel {
                stage('Unit') {
                    steps {
                        sh 'pnpm run test:front:ci'
                    }
                    post {
                        always {
                            junit(
                                testResults: 'junit/vitest.xml',
                                allowEmptyResults: true
                            )
                        }
                    }
                }
                stage('E2E') {
                    environment {
                        COMPOSE_PROJECT = "${PROJECT_NAME}-${env.BUILD_ID}"
                        COMPOSE_PARAMS = "-p ${env.COMPOSE_PROJECT} -f test/cypress/docker-compose.yml --project-directory ."
                    }
                    steps {
                        script {
                            sh 'rm -f junit/e2e-*.xml'
                            sh 'rm -rf test/cypress/screenshots'
                            env.COMPOSE_TAG = PROTECTED_BRANCH.contains(env.CHANGE_TARGET) ? env.CHANGE_TARGET : 'dev'

                            def modules = sh(
                                script: "node test/cypress/docker/find/find.js ${env.COMPOSE_TAG}",
                                returnStdout: true
                            ).trim()
                            echo "E2E MODULES: ${modules}"

                            script {
                                sh "docker compose ${env.COMPOSE_PARAMS} up -d"
                                def image = docker.build('lilium-dev', '-f docs/Dockerfile.dev docs')
                                image.inside("--network ${env.COMPOSE_PROJECT}_default -e CI -e TZ --init") {
                                    sh "sh test/cypress/docker/cypressParallel.sh 1 '${modules}'"
                                }
                            }
                        }
                    }
                    post {
                        always {
                            sh "docker compose ${env.COMPOSE_PARAMS} down -v"
                            archiveArtifacts artifacts: 'test/cypress/screenshots/**/*', allowEmptyArchive: true
                            junit(
                                testResults: 'junit/e2e-*.xml',
                                allowEmptyResults: true
                            )
                        }
                    }
                }
            }
        }
        stage('Build') {
            when {
                expression { IS_PROTECTED_BRANCH }
            }
            environment {
                VERSION = readFile 'VERSION.txt'
            }
            steps {
                sh 'quasar build'
                dockerBuild 'salix-frontend', '.'
            }
        }
        stage('Deploy') {
            when {
                expression { IS_PROTECTED_BRANCH }
            }
            environment {
                VERSION = readFile 'VERSION.txt'
            }
            steps {
                withKubeConfig([
                    serverUrl: "$KUBERNETES_API",
                    credentialsId: 'kubernetes',
                    namespace: 'lilium'
                ]) {
                    sh 'kubectl set image deployment/lilium-$BRANCH_NAME lilium-$BRANCH_NAME=$REGISTRY/salix-frontend:$VERSION'
                }
            }
        }
    }
}

def dockerBuild(imageName, context, dockerfile = null) {
    if (dockerfile == null)
        dockerfile = "${context}/Dockerfile"

    def certDir = '/home/jenkins/.buildkit/certs'
    def buildxArgs = [
        "--name=buildkitd",
        "--driver=remote",
        "--driver-opt="
            + "cacert=${certDir}/ca.pem,"
            + "cert=${certDir}/cert.pem,"
            + "key=${certDir}/key.pem,"
            + "servername=buildkitd",
        "tcp://buildkitd:1234"
    ]

    def cacheImage = "${env.REGISTRY_CACHE}/${imageName}"
    def pushImage = "${env.REGISTRY}/${imageName}"
    def baseImage = "${pushImage}:${env.VERSION}"

    def buildArgs = [
        context,
        "--push",
        "--builder=buildkitd",
        "--file=${dockerfile}",
        "--cache-from=type=registry,ref=${cacheImage}:cache-${env.BRANCH_NAME}",
        "--cache-from=type=registry,ref=${cacheImage}:cache-dev",
        "--cache-to=type=registry,ref=${cacheImage}:cache-${env.BRANCH_NAME},mode=max",
        "--tag=${pushImage}:${env.BRANCH_NAME}"
    ]

    def isLatest = ['master', 'main'].contains(env.BRANCH_NAME)
    if (isLatest)
        buildArgs.push("--tag=${pushImage}:latest")

    // FIXME: Nested docker.withRegistry() does not work
    // https://issues.jenkins.io/browse/JENKINS-59777
    withCredentials([usernamePassword(
        credentialsId: 'registry-cache',
        usernameVariable: 'CACHE_USR',
        passwordVariable: 'CACHE_PSW')
    ]) {
        docker.withRegistry("https://${env.REGISTRY}", 'docker-registry') {
            sh 'echo "$CACHE_PSW" | docker login --username "$CACHE_USR" --password-stdin "http://$REGISTRY_CACHE"'
            sh "docker buildx create ${buildxArgs.join(' ')}"
            docker.build(baseImage, buildArgs.join(' '))
        }
    }
}