salix/Jenkinsfile

#!/usr/bin/env groovy
pipeline {
    agent any
    options {
        disableConcurrentBuilds()
    }
    environment {
        PROJECT_NAME = 'salix'
        STACK_NAME = "${env.PROJECT_NAME}-${env.BRANCH_NAME}"
    }
    stages {
        stage('Checkout') {
            steps {
                script {
                    switch (env.BRANCH_NAME) {
                        case 'master':
                            env.NODE_ENV = 'production'
                            env.BACK_REPLICAS = 4
                            break
                        case 'test':
                            env.NODE_ENV = 'test'
                            env.BACK_REPLICAS = 2
                            break
                        case 'dev':
                            env.NODE_ENV = 'dev'
                            break
                    }

                    env.GIT_COMMIT_MSG = sh(
                        script: 'git log -1 --pretty=%B ${GIT_COMMIT}',
                        returnStdout: true
                    ).trim()

                    if (env.JOB_NAME.startsWith('gitea/'))
                        env.RUN_SOURCE = 'git'
                }
                setEnv()
            }
        }
        stage('Install') {
            environment {
                NODE_ENV = ""
            }
            steps {
                nodejs('node-v20') {
                    sh 'npm install --no-audit --prefer-offline'
                    sh 'gulp install --ci'
                }
            }
        }
        stage('Test') {
            when {
                environment name: 'RUN_SOURCE', value: 'git'
                not { anyOf {
                    branch 'test'
                    branch 'master'
                }}
            }
            environment {
                NODE_ENV = ""
                TZ = 'Europe/Madrid'
            }
            parallel {
                stage('Frontend') {
                    steps {
                        nodejs('node-v20') {
                            sh 'jest --ci --reporters=default --reporters=jest-junit --maxWorkers=6'
                        }
                    }
                }
                stage('Backend') {
                    steps {
                        nodejs('node-v20') {
                            sh 'npm run test:back:ci'
                        }
                    }
                }
            }
        }
        stage('Build') {
            when {
                environment name: 'RUN_SOURCE', value: 'git'
                anyOf {
                    branch 'test'
                    branch 'master'
                }
            }
            environment {
                CREDENTIALS = credentials('docker-registry')
            }
            steps {
                nodejs('node-v20') {
                    sh 'gulp build'
                }

                dockerBuild()
            }
        }
        stage('Deploy') {
            when {
                environment name: 'RUN_SOURCE', value: 'git'
                anyOf {
                    branch 'test'
                    branch 'master'
                }
            }
            environment {
                DOCKER_HOST = "${env.SWARM_HOST}"
            }
            steps {
                sh "docker stack deploy --with-registry-auth --compose-file docker-compose.yml ${env.STACK_NAME}"
            }
        }
        stage('Database') {
            when { anyOf {
                branch 'dev'
                branch 'test'
                branch 'master'
            }}
            steps {
                configFileProvider([
                    configFile(fileId: "config.${env.NODE_ENV}.ini",
                    variable: 'MYSQL_CONFIG')
                ]) {
                    sh 'mkdir -p db/remotes'
                    sh 'cp "$MYSQL_CONFIG" db/remotes/$NODE_ENV.ini'
                }
                nodejs('node-v20') {
                    sh 'npx myt push $NODE_ENV --force --commit'
                }
            }
        }
    }
    post {
        success {
            script {
                if (env.RUN_SOURCE == 'git'
                && ['master', 'test', 'dev'].contains(env.BRANCH_NAME)) {
                    String message = env.GIT_COMMIT_MSG
                    int index = message.indexOf('\n')
                    if (index != -1)
                        message = message.substring(0, index)

                    rocketSend(
                        channel: 'vn-database',
                        message: "*DB version uploaded:* ${message}"
                            +"\n$COMMITTER_EMAIL ($BRANCH_NAME)"
                            +"\n$GIT_URL/commit/$GIT_COMMIT",
                        rawMessage: true
                    )
                }
            }
        }
        always {
            script {
                if (env.RUN_SOURCE == 'git'
                && !['master', 'test'].contains(env.BRANCH_NAME)) {
                    try {
                        junit 'junitresults.xml'
                        junit 'junit.xml'
                    } catch (e) {
                        echo e.toString()
                    }
                }

                if (!env.COMMITTER_EMAIL || currentBuild.currentResult == 'SUCCESS') return;
                try {
                    mail(
                        to: env.COMMITTER_EMAIL,
                        subject: "Pipeline: ${env.JOB_NAME} (${env.BUILD_NUMBER}): ${currentBuild.currentResult}",
                        body: "Check status at ${env.BUILD_URL}"
                    )
                } catch (e) {
                    echo e.toString()
                }
            }
        }
    }
}