vn-access/setup.iss

#define MyAppName "Verdnatura"
#define MyAppVersion "1.1"
#define MyAppPublisher "Verdnatura"
#define MyAppURL "http://www.verdnatura.es/"

[Setup]
; NOTE: The value of AppId uniquely identifies this application.
AppId={{1BFBC7A1-64B3-41E0-8A8E-0D29043EA8A3}
AppName={#MyAppName}
AppVersion={#MyAppVersion}
AppVerName={#MyAppName} {#MyAppVersion}
AppPublisher={#MyAppPublisher}
AppPublisherURL={#MyAppURL}
AppSupportURL={#MyAppURL}
AppUpdatesURL={#MyAppURL}
CreateAppDir=yes
DefaultDirName={pf}\{#MyAppName}
DefaultGroupName={#MyAppName}
;LicenseFile=src\LICENSE.txt
SetupIconFile=src\icon.ico
UninstallDisplayIcon={app}\icon.ico
Compression=lzma
SolidCompression=yes
PrivilegesRequired=admin
DisableStartupPrompt=yes
OutputDir=..
OutputBaseFilename=vn-access
SignTool=signtool.exe sign \
  /a /f $qC:\cert.pfx$q /n $q{#MyAppPublisher}$q /t http://timestamp.comodoca.com/authenticode /d $q{#MyAppName}$q $f

[Languages]
Name: "es"; MessagesFile: "compiler:Languages\Spanish.isl"

[Dirs]
Name: "{app}"; \
  Flags: uninsalwaysuninstall
Name: "{sd}\fotos"; \
  Flags: uninsalwaysuninstall; \
  Permissions: users-modify

[Files]
Source: "src\*"; \
  DestDir: "{app}"; Flags: ignoreversion
Source: "icons\*"; \
  DestDir: "{app}\icons"; Flags: ignoreversion
Source: "fonts\*"; \
  DestDir: "{fonts}"; Flags: onlyifdoesntexist uninsneveruninstall
Source: "ocx\*"; \
  DestDir: {sys}; Flags: onlyifdoesntexist regserver 32bit
Source: "deps\*"; \
  DestDir: {tmp}; Flags: deleteafterinstall; AfterInstall: InstallDep;

[Tasks]
Name: "desktopicon"; \
  Description: "{cm:CreateDesktopIcon}"; \
  GroupDescription: "{cm:AdditionalIcons}";

[Components]
Name: "tpv"; \
  Description: "Terminal Punto Venta"; \
  Types: full compact
Name: "ent"; \
  Description: "Entradas"; \
  Types: full compact
Name: "com"; \
  Description: "Comparativa"; \
  Types: full compact
Name: "enc"; \
  Description: "Encajado"; \
  Types: full
Name: "eti"; \
  Description: "Etiquetas"; \
  Types: full
Name: "lab"; \
  Description: "Laboral"; \
  Types: full

[Icons]
Name: "{group}\Terminal Punto Venta"; \
  Parameters: "tpv"; \
  IconFileName: "{app}\icons\tpv.ico"; \
  FileName: "{app}\vn-access.hta"; \
  WorkingDir: "{app}"; \
  Components: tpv
Name: "{group}\Entradas"; \
  Parameters: "ent"; \
  IconFileName: "{app}\icons\ent.ico"; \
  FileName: "{app}\vn-access.hta"; \
  WorkingDir: "{app}"; \
  Components: ent
Name: "{group}\Comparativa"; \
  Parameters: "com"; \
  IconFileName: "{app}\icons\com.ico"; \
  FileName: "{app}\vn-access.hta"; \
  WorkingDir: "{app}"; \
  Components: com
Name: "{group}\Encajado"; \
  Parameters: "enc"; \
  IconFileName: "{app}\icons\enc.ico"; \
  FileName: "{app}\vn-access.hta"; \
  WorkingDir: "{app}"; \
  Components: enc
Name: "{group}\Etiquetas"; \
  Parameters: "eti"; \
  IconFileName: "{app}\icons\eti.ico"; \
  FileName: "{app}\vn-access.hta"; \
  WorkingDir: "{app}"; \
  Components: eti
Name: "{group}\Laboral"; \
  Parameters: "lab"; \
  IconFileName: "{app}\icons\lab.ico"; \
  FileName: "{app}\vn-access.hta"; \
  WorkingDir: "{app}"; \
  Components: lab

;Desktop icons

Name: "{commondesktop}\Terminal Punto Venta"; \
  Parameters: "tpv"; \
  IconFileName: "{app}\icons\tpv.ico"; \
  FileName: "{app}\vn-access.hta"; \
  WorkingDir: "{app}"; \
  Tasks: desktopicon; \
  Components: tpv
Name: "{commondesktop}\Entradas"; \
  Parameters: "ent"; \
  IconFileName: "{app}\icons\ent.ico"; \
  FileName: "{app}\vn-access.hta"; \
  WorkingDir: "{app}"; \
  Tasks: desktopicon; \
  Components: ent
Name: "{commondesktop}\Comparativa"; \
  Parameters: "com"; \
  IconFileName: "{app}\icons\com.ico"; \
  FileName: "{app}\vn-access.hta"; \
  WorkingDir: "{app}"; \
  Tasks: desktopicon; \
  Components: com
Name: "{commondesktop}\Encajado"; \
  Parameters: "enc"; \
  IconFileName: "{app}\icons\enc.ico"; \
  FileName: "{app}\vn-access.hta"; \
  WorkingDir: "{app}"; \
  Tasks: desktopicon; \
  Components: enc
Name: "{commondesktop}\Etiquetas"; \
  Parameters: "eti"; \
  IconFileName: "{app}\icons\eti.ico"; \
  FileName: "{app}\vn-access.hta"; \
  WorkingDir: "{app}"; \
  Tasks: desktopicon; \
  Components: eti
Name: "{commondesktop}\Laboral"; \
  Parameters: "lab"; \
  IconFileName: "{app}\icons\lab.ico"; \
  FileName: "{app}\vn-access.hta"; \
  WorkingDir: "{app}"; \
  Tasks: desktopicon; \
  Components: lab
   
[Code]

procedure InstallDep;
var
  StatusText: String;
  ResultCode: Integer;
  MsiFile: String;
begin
  MsiFile := ExpandConstant(CurrentFilename);
  StatusText := WizardForm.StatusLabel.Caption;
  WizardForm.StatusLabel.Caption := CurrentFilename +'...';
  WizardForm.ProgressGauge.Style := npbstMarquee;
  Log(WizardSelectedComponents(False));
  try
    if not Exec('msiexec', '/quiet /i '+ MsiFile, '', SW_SHOW, ewWaitUntilTerminated, ResultCode) then
    begin
      MsgBox(CurrentFilename +' installation failed with code: ' + IntToStr(ResultCode) + '.',
        mbError, MB_OK);
      WizardForm.Close;       
    end;
  finally
    WizardForm.StatusLabel.Caption := StatusText;
    WizardForm.ProgressGauge.Style := npbstNormal;
  end;
end;