vn-autoconfig/Jenkinsfile

#!/usr/bin/env groovy

pipeline {
    agent any
    environment {
        PROJECT_NAME = 'vn-autoconfig'
    }
    stages {
        stage('Checkout') {
            steps {
                script {
                    if (!env.GIT_COMMITTER_EMAIL) {
                        env.COMMITTER_EMAIL = sh(
                            script: 'git --no-pager show -s --format="%ae"',
                            returnStdout: true
                        ).trim()
                    } else {
                        env.COMMITTER_EMAIL = env.GIT_COMMITTER_EMAIL;
                    }
                }

                configFileProvider([
                    configFile(fileId: "${env.PROJECT_NAME}.groovy",
                    variable: 'GROOVY_FILE')
                ]) {
                    load env.GROOVY_FILE
                }

                sh 'printenv'
            }
        }
        stage('Build') {
            when {
                branch 'master'
            }
            environment {
                CREDS = credentials('docker-registry')
            }
            steps {
                sh 'docker login --username $CREDS_USR --password $CREDS_PSW $REGISTRY'
                sh 'docker-compose build --parallel'
                sh 'docker-compose push'
            }
        }
        stage('Deploy') {
            when {
                branch 'master'
            }
            steps {
                sh "docker stack deploy --with-registry-auth --prune --compose-file docker-compose.yml ${env.PROJECT_NAME}"
            }
        }
    }
    post {
        always {
            script {
                if (!env.COMMITTER_EMAIL) return
                try {
                    mail(
                        to: env.COMMITTER_EMAIL,
                        subject: "Pipeline: ${env.JOB_NAME} (${env.BUILD_NUMBER}): ${currentBuild.currentResult}",
                        body: "Check status at ${env.BUILD_URL}"
                    )
                } catch (e) {
                    echo e.toString()
                }
            }
        }
    }
}